Tool Backup Data Acunetix

Berikut ini adalah tool backup data Acunetix dalam format bat file yang dapat dijalankan di environment OS Windows.

Perintah di dalam bat file akan memanfaatkan tool software 7-ZIP, jadi pastikan aplikasi 7-ZIP sudah terinstal terlebih dahulu di host server Acunetix.

Buat file dengan nama axbak.bat, lalu isi dengan script dibawah ini:

@echo off
setlocal enableextensions

REM ==== Konfigurasi ====
set "ZIP=C:\Program Files\7-Zip\7z.exe"

REM Remote SMB share (folder tujuan di server lain)
REM Ganti dan sesuaikan nama "BACKUP-SRV" dengan nama host untuk tampung file backup
set "REMOTE_SHARE=\\BACKUP-SRV\AcunetixBackup$\ax"

REM Jika butuh credential khusus, isi ini. Kalau tidak, kosongkan dan script akan coba akses langsung.
set "REMOTE_USER=DOMAIN\UserBackup"
set "REMOTE_PASS=PasswordKuat!"

REM Nama file backup (pakai timestamp sederhana: YYYYMMDD_HHMMSS)
for /f %%i in ('powershell -NoProfile -Command "Get-Date -Format yyyyMMdd_HHmmss"') do set "TS=%%i"
set "REMOTE_ZIP=%REMOTE_SHARE%\ax_backup_%COMPUTERNAME%_%TS%.zip"

REM ==== Stop service ====
net stop "Acunetix Supervisor"
net stop "Acunetix Database"

REM ==== Pastikan remote share bisa diakses ====
if not "%REMOTE_USER%"=="" (
  net use "%REMOTE_SHARE%" /user:"%REMOTE_USER%" "%REMOTE_PASS%" /persistent:no
  if errorlevel 1 goto :FAIL
)

if not exist "%REMOTE_SHARE%\" goto :FAIL

REM ==== Buat ZIP langsung ke remote ====
"%ZIP%" a -tzip "%REMOTE_ZIP%" "C:\ProgramData\Acunetix" -x!"Acunetix\certs"
if errorlevel 1 goto :FAIL

REM ==== Disconnect credential mapping (kalau dipakai) ====
if not "%REMOTE_USER%"=="" (
  net use "%REMOTE_SHARE%" /delete >nul 2>&1
)

REM ==== Start service ====
net start "Acunetix Database"
net start "Acunetix Supervisor"

echo Backup OK: %REMOTE_ZIP%
exit /b 0

:FAIL
echo Backup FAILED. Cek akses ke %REMOTE_SHARE% dan path 7-Zip.
REM Pastikan service Acunetix kembali running walau proses backup gagal
net start "Acunetix Database" >nul 2>&1
net start "Acunetix Supervisor" >nul 2>&1
if not "%REMOTE_USER%"=="" (
  net use "%REMOTE_SHARE%" /delete >nul 2>&1
)
exit /b 1

Script diatas bersumber dari dokumentasi website Acunetix dengan url : https://www.acunetix.com/support/docs/faqs/migrating-acunetix-on-premises-to-another-server/

Tapi untuk kebutuhan agar hasil data backup bisa langsung simpan di host server berbeda dilakukan sedikit modifikasi.

Setelah file axbak.bat selesai dibuat, dan untuk menjalankannya pastikan diberlakukan pada CMD dengan privilege “Run as Administrator”.

Hasil backup di remote host server nantinya dalam bentuk file .ZIP , dengan standarisasi penamaan :

ax_backup_<NAMA_SERVER>_<YYYYMMDD_HHMMSS>.zip 

Semoga bermanfaat.